cpu.vbs - vbscript script by ActiveXperts Software
cpu.vbs checks CPU usage on a host.
Use cpu.vbs directly from ActiveXperts Network Monitor; in the Manager's 'Monitor' menu, select 'New Check (Script)' and select cpu.vbs. Configure the required parameter, or press 'Load a working sample'.
In ActiveXperts Network Monitor, Administrators can use three different scripting languages: Powershell, VBScript and SSH.
cpu.vbs script code
' ///////////////////////////////////////////////////////////////////////////////
' // ActiveXperts Network Monitor - VBScript based checks
' // For more information about ActiveXperts Network Monitor and VBScript, visit
' // http://www.activexperts.com/support/network-monitor/online/vbscript/
' ///////////////////////////////////////////////////////////////////////////////
Option Explicit
' Declaration of global variables
Dim SYSDATA, SYSEXPLANATION ' SYSDATA is displayed in the 'Data' column in the Manager; SYSEXPLANATION in the 'LastResponse' column
' Constants - return values
Const retvalUnknown = 1 ' ActiveXperts Network Monitor functions should always return True (-1, Success), False (0, Error) or retvalUnknown (1, Uncertain)
' // To test a function outside Network Monitor (e.g. using CSCRIPT from the
' // command line), remove the comment character (') in the following lines:
' Dim bResult
' bResult = CheckCpuUsage( "localhost", "dell12", "_Total", 80 )
' WScript.Echo "Return value: [" & bResult & "]"
' WScript.Echo "SYSDATA: [" & SYSDATA & "]"
' WScript.Echo "SYSEXPLANATION: [" & SYSEXPLANATION & "]"
Function CheckCpuUsage( strHost, strAltCredentials, strCPU, nMaxCpuUsage )
' Description:
' Checks CPU usage on a (remote) computer.
' Parameters:
' 1) strHost As String - Hostname or IP address of the computer you want to monitor
' 2) strAltCredentials As String - Specify an empty string to use Network Monitor service credentials.
' To use alternate credentials, enter a server that is defined in Server Credentials table.
' (To define Server Credentials, choose Tools->Options->Server Credentials)
' 3) strCpu As String - CPU that you want to monitor. Syntax: CPUx, where x is a zero based index
' 4) nMaxCpuUsage As Number - Maximum allowed CPU usage (%)
' Usage:
' CheckCpuUsage( "<Hostname | IP>", "<Empty String | Server>", "<_Total|0|1|...>", <Max_Cpu_Percent> )
' Sample:
' CheckCpuUsage( "localhost", "", "_Total", 60 )
Dim strAltLogin, strAltPassword, objWMIService
CheckCpuUsage = retvalUnknown ' Default return value, and will be shown as a yellow (uncertain) icon in the Manager
SYSDATA = "" ' SYSDATA displayed in the 'Data' column in the Manager
SYSEXPLANATION = "" ' SYSEXPLANATION displayed in the 'LastResponse' column in the Manager
strAltLogin = ""
strAltPassword = ""
' If alternate credentials are specified, retrieve the alternate login and password from the ActiveXperts global settings
If( strAltCredentials <> "" ) Then
If( Not getCredentials( strHost, strAltCredentials, strAltLogin, strAltPassword, SYSEXPLANATION )) Then
Exit Function
End If
End If
' WMI Connect
If( Not wmiConnect( strHost, strAltLogin, strAltPassword, objWMIService, SYSEXPLANATION ) ) Then
Exit Function
End If
CheckCpuUsage = checkCpuUsageWMI( objWMIService, strHost, strCPU, nMaxCpuUsage, SYSDATA, SYSEXPLANATION )
End Function
' //////////////////////////////////////////////////////////////////////////////
' // --- Private Functions section ---
' // Private functions names should start with a lower case character, so they
' // will not be listed in the Network Monitor's function browser.
' //////////////////////////////////////////////////////////////////////////////
Function checkCpuUsageWMI( objWMIService, strHost, strCPU, nMaxCpuUsage, BYREF strSysData, BYREF strSysExplanation )
Dim nCpuUsage, colCPUs, objCPU
checkCpuUsageWMI = retvalUnknown ' Default return value
Set colCPUs = Nothing
On Error Resume Next
Set colCPUs = objWMIService.ExecQuery( "Select * from Win32_PerfFormattedData_PerfOS_Processor" )
If( Err.Number <> 0 ) Then
strSysData = ""
strSysExplanation = "Unable to query WMI class on computer [" & strHost & "]"
Exit Function
End If
If( colCPUs.Count <= 0 ) Then
strSysData = ""
strSysExplanation = "Win32_PerfFormattedData_PerfOS_Processor class does not exist on computer [" & strHost & "]"
Exit Function
End If
On Error Goto 0
For Each objCPU In colCPUs
If( objCpu.Name = strCPU ) Then
nCpuUsage = CInt( objCpu.PercentProcessorTime )
strSysData = objCpu.PercentProcessorTime
strSysExplanation = "CPU usage=[" & nCpuUsage & "%], maximum allowed=[" & nMaxCpuUsage & "%]"
If( nCpuUsage > nMaxCpuUsage ) Then
strSysExplanation = "CPU usage=[" & nCpuUsage & "%], maximum allowed=[" & nMaxCpuUsage & "%]"
checkCpuUsageWMI = False
Else
strSysExplanation = "CPU usage=[" & nCpuUsage & "%], maximum allowed=[" & nMaxCpuUsage & "%]"
checkCpuUsageWMI = True
End If
Exit Function
End If
Next
checkCpuUsageWMI = retvalUnknown
strSysData = ""
strSysExplanation = "Unable to query [" & strCPU & "] on computer [" & strHost & "]"
End Function
' //////////////////////////////////////////////////////////////////////////////
Function getCredentials( strHost, strAltCredentials, BYREF strAltLogin, BYREF strAltPassword, BYREF strSysExplanation )
Dim objNMServerCredentials
strAltLogin = ""
strAltPassword = ""
strSysExplanation = ""
getCredentials = False
If( strAltCredentials = "" ) Then
' No alternate credentials specified, so login and password are empty and service credentials will be used
getCredentials = True
Exit Function
End If
Set objNMServerCredentials = CreateObject( "ActiveXperts.NMServerCredentials" )
strAltLogin = objNMServerCredentials.GetLogin( strAltCredentials )
strAltPassword = objNMServerCredentials.GetPassword( strAltCredentials )
If( strAltLogin = "" ) Then
getCredentials = False
strSysExplanation = "No alternate credentials defined for [" & strAltCredentials & "]. In the Manager application, select 'Options' from the 'Tools' menu and select the 'Server Credentials' tab to enter alternate credentials"
Exit Function
End If
getCredentials = True
End Function
' //////////////////////////////////////////////////////////////////////////////
Function wmiConnect( strHost, strAltLogin, strAltPassword, BYREF objWMIService, BYREF strSysExplanation )
Dim objSWbemLocator, colItems
Dim bConnectResult
wmiConnect = False
Set objWMIService = Nothing
If( strAltLogin = "" ) Then
' Connect to remote host on same domain using same security context
On Error Resume Next
Set objWMIService = GetObject( "winmgmts:{impersonationLevel=Impersonate}!\\" & strHost &"\root\cimv2" )
If( Err.Number <> 0 ) Then
bConnectResult = False
Else
bConnectResult = True
End If
On Error Goto 0
Else
' Connect to remote host using different security context and/or different domain
On Error Resume Next
Set objSWbemLocator = CreateObject( "WbemScripting.SWbemLocator" )
Set objWMIService = objSWbemLocator.ConnectServer( strHost, "root\cimv2", strAltLogin, strAltPassword )
If( Err.Number <> 0 ) Then
bConnectResult = False
Else
bConnectResult = True
End If
objWMIService.Security_.ImpersonationLevel = 3
On Error Goto 0
End If
If( Not bConnectResult ) Then
Set objWMIService = Nothing
wmiConnect = False
strSysExplanation = "Unable to connect to [" & strHost & "]. Possible reasons: no WMI installed on the remote server, firewall blocking WMI calls, login failure, or remote server down"
Exit Function
End If
wmiConnect = True
End Function