VBScript FTP Client Sample Source Code

Network Component provides an easy-to-use development interface to a variety of IP protocols. By using Network Component, you can very easily create or enhance applications with network features.

Network Component features the following: DNS, FTP, HTTP, HTTPs, ICMP Ping, IP-to-Country, MSN, NTP, RSH, SCP, SFTP, SNMP v1/v2c (Get, GetNext, Set), SNMP Traps, SNMP MIB, SSH, TCP, Telnet, TFTP, UDP, Telnet, Wake-On-LAN and more.

Network Component can be well integrated into any development platform that supports ActiveX objects.

This document describes how the Network Component FtpServer object can be integrated into your projects.

The most important functions of the FtpServer object are:

Connect - connect to the (remote) FTP server on port 21 or any alternate port;
Disconnect - to diconnect after a connect call;
GetCurrentDir - retrieve the current directory;
ChangeDir - change the current directory;
CreateDir - create a new directory;
RenameDir - rename a directory;
DeleteDir - delete a directory;
FindFile - find a specific file in the current directory;
FindFirstFile - iterate over all files in the current directory; find the first file;
FindNextFile - iterate over all files in the current directory; find the next file;
RenameFile - rename a file in the current directory;
DeleteFile - delete a file in the current directory;
GetFile - get (download) a file, either using binary transfer or ASCII transfer;
PutFile - put (upload) a file, either using binary transfer or ASCII transfer;

Step 1: Download and install the Network Component

Download Network Component from the ActiveXperts Download Site and start the installation. The installation guides you through the installation process.

Step 2: Create a new script

Create a new script using your favorite editor. You can simply use notepad. However, a VBScript editor is recommended, so you can browse through objects, objects properties and object functions.

You're now able to write a more advanced script to communicate using the Network Component.

Step 3: Create the Network Component object in VBScript

Create a new VBScript file called DEMO.VBS. It is recommended to insert the following line on top of your code:

Option Explicit

This statement requires that all variable names be defined (with the Dim statement), to avoid simple typos that can cause incredible headaches and long debugging sessions for something that should have never happened.

Now, declare the Network Component object(s):

Dim objFtpServer

Create the Network Component object(s) like this:

Set objFtpServer      = CreateObject( "AxNetwork.FtpServer" )

Now, add the following lines to the file to have your first Network Component VBScript program:

WScript.Echo "Version: " & objFtpServer.Version
WScript.Echo "License Status: " & objFtpServer.License Status

Appendix: Full source code

You can now connect to a remote FTP server, logon, change directory and perform file operations.

The following VBScript code shows how to list files in a specific directory on a remote FTP server:

' ********************************************************************
' ActiveXperts Network Component sample - FTPGET
'  FTP Sample: Connect to an FTP server, and show all files in a specific directory
' Written by ActiveXperts Software 
'   https://www.activexperts.com
' ********************************************************************

Option Explicit

Dim objConstants, objFtpServer, objFtpFile, fso, strSaveAs

Set objFtpServer = CreateObject( "AxNetwork.FtpServer" )

' A license key is required to unlock this component after the trial period has expired.
' Call 'Activate' with a valid license key as its first parameter. Second parameter determines whether to save the license key permanently 
' to the registry (True, so you need to call Activate only once), or not to store the key permanently (False, so you need to call Activate
' every time the component is created). For details, see manual, chapter "Product Activation".
'
' objFtpServer.Activate "XXXXX-XXXXX-XXXXX", False

' Component info
Wscript.Echo "ActiveXpert Network Component " & objFtpServer.Version
Wscript.Echo "Build: " & objFtpServer.Build & vbCrLf & "Module: " & objFtpServer.Module
Wscript.Echo "License Status: " & objFtpServer.LicenseStatus & vbCrLf & "License Key: " & objFtpServer.LicenseKey & vbCrLf

' Set Logfile
Set fso = CreateObject( "Scripting.FileSystemObject")
objFtpServer.LogFile = fso.GetSpecialFolder(2) & "\Ftp.log"
WScript.Echo "Log file: " & objFtpServer.LogFile & vbCrLf

' Connect to the remote FTP server
objFtpServer.Connect "ftp.activexperts-lab.com", "anonymous", "me@myself.dom" 
Wscript.Echo "Connect, result: " & objFtpServer.LastError & " (" & objFtpServer.GetErrorDescription ( objFtpServer.LastError ) & ")"
If( objFtpServer.LastError <> 0 ) Then
   Wscript.Echo "Ready."
   WScript.Quit
End If

' Show last response of FTP server
WScript.Echo "Last response: " & objFtpServer.LastResponse

' Use binary transfer for GetFile calls
objFtpServer.BinaryTransfer = True

' Change directory
objFtpServer.ChangeDir "/Samples/network-component" 
Wscript.Echo "ChangeDir, result: " & objFtpServer.LastError & " (" & objFtpServer.GetErrorDescription ( objFtpServer.LastError ) & ")"
If( objFtpServer.LastError <> 0 ) Then
   objFtpServer.Disconnect
   Wscript.Echo "Disconnected."
   Wscript.Echo "Ready."
   WScript.Quit
End If

' Iterate over all files
Set objFtpFile = objFtpServer.FindFirstFile()
Wscript.Echo "Find file, result: " & objFtpServer.LastError & " (" & objFtpServer.GetErrorDescription ( objFtpServer.LastError ) & ")"
' WScript.Echo "Last response: " & objFtpServer.LastResponse
While ( objFtpServer.LastError = 0 )

   WScript.Echo "Name: " & objFtpFile.Name 
   WScript.Echo "   IsDirectory: " & objFtpFile.IsDirectory
   WScript.Echo "   Size (bytes): " & objFtpFile.Size
   WScript.Echo "   Last modified date (seconds): " & objFtpFile.DateSeconds
   WScript.Echo "   Last modified date: " & objFtpFile.Date
    
   ' To save the file, call the GetFile function. 
   ' strSaveAs = "C:\temp\" & objFtpFile.Name
   ' objFtpServer.GetFile objFtpFile.Name, strSaveAs 
   ' Wscript.Echo "Save file as " & strSaveAs & ", result: " & objFtpServer.LastError & " (" & objFtpServer.GetErrorDescription ( objFtpServer.LastError ) & ")"

   ' To delete a file, call the DeleteFile function. 
   ' objFtpServer.DeleteFile objFtpFile.Name
   ' Wscript.Echo "Delete file, result: " & objFtpServer.LastError & " (" & objFtpServer.GetErrorDescription ( objFtpServer.LastError ) & ")"

   Set objFtpFile = objFtpServer.FindNextFile()
   Wscript.Echo "Find file, result: " & objFtpServer.LastError & " (" & objFtpServer.GetErrorDescription ( objFtpServer.LastError ) & ")"
Wend

objFtpServer.Disconnect
Wscript.Echo "Disconnected."
Wscript.Echo "Ready."

You can download the complete samples here. There are many other working Network Component scripts on our site and shipped with the product.

Contact Info

ActiveXperts Network Component

Crumbtrail

VBScript FTP Client Sample Source Code

Step 1: Download and install the Network Component

Step 2: Create a new script

Step 3: Create the Network Component object in VBScript

Appendix: Full source code