ActiveXperts Network Component

Quicklinks

How to use SNMP Trap Receiver in VBScript

Network Component provides an easy-to-use development interface to a variety of IP protocols. By using Network Component, you can very easily create or enhance applications with network features.

Network Component features the following: DNS, FTP, HTTP, HTTPs, ICMP Ping, IP-to-Country, MSN, NTP, RSH, SCP, SFTP, SNMP v1/v2c (Get, GetNext, Set), SNMP Traps, SNMP MIB, SSH, TCP, Telnet, TFTP, UDP, Telnet, Wake-On-LAN and more.

Network Component can be well integrated into any development platform that supports ActiveX objects.


Network Component is compliant with SNMP v1 and SNMP v2c. Several SNMP data types are supported, including:

  • String types (also called "octet strings");
  • Integer types (16bit, 32bit, 64bit and unsigned integers);
  • IP Address types;
  • Timetick types;
  • Counter types (32bit and 64bit counters);
  • OID types (also called "Object ID's");
  • Other, less frequently used datatypes.

Network Component SNMP traps features:

  • SNMP v1 and SNMP v2c support;
  • Support for aplphanumeric OID's (object identifier) and numeric OID's;
  • Multi-threading architecture: send SNMP traps simultaneously from one process using multiple threads;
  • Support for ports other than the default 161 and 162 ports;
  • Support for enterprise specific traps;
  • Support for SNMP v1 generic traps;
  • Send multiple variables in a single SNMP TRAP message.

Step 1: Download and install the Network Component

Download Network Component from the ActiveXperts Download Site and start the installation. The installation guides you through the installation process.

Step 2: Create a new script

Create a new script using your favorite editor. You can simply use notepad. However, a VBScript editor is recommended, so you can browse through objects, objects properties and object functions.

You're now able to write a more advanced script to communicate using the Network Component.

Step 3: Create the Network Component object in VBScript

Create a new VBScript file called DEMO.VBS. It is recommended to insert the following line on top of your code:

Option Explicit

This statement requires that all variable names be defined (with the Dim statement), to avoid simple typos that can cause incredible headaches and long debugging sessions for something that should have never happened.

Now, declare the Network Component object(s):

Dim objSnmpTrapManager

Create the Network Component object(s) like this:

Set objSnmpTrapManager      = CreateObject( "AxNetwork.SnmpTrapManager" )

Now, add the following lines to the file to have your first Network Component VBScript program:

WScript.Echo "Version: " & objSnmpTrapManager.Version
WScript.Echo "License Status: " & objSnmpTrapManager.LicenseStatus

Appendix: Full source code

' ********************************************************************
' ActiveXperts Network Component sample - Receive SNMP Trap
'   
' Written by ActiveXperts Software 
'     http://www.activexperts.com
' ********************************************************************

Option Explicit

' Declare variables
Dim objSnmpTrapManager, objSnmpTrap, objSnmpObject, objConstants, fso
Dim strMibFile, i

' Create SnmpTrapManager and NwConstants instances
Set objSnmpTrapManager  = CreateObject( "AxNetwork.SnmpTrapManager" )
Set objConstants        = CreateObject( "AxNetwork.NwConstants" )

' A license key is required to unlock this component after the trial period has expired.
' Call 'Activate' with a valid license key as its first parameter. Second parameter determines whether to save the license key permanently 
' to the registry (True, so you need to call Activate only once), or not to store the key permanently (False, so you need to call Activate
' every time the component is created). For details, see manual, chapter "Product Activation".
'
' objSnmpTrapManager.Activate "XXXXX-XXXXX-XXXXX", False

' Component info
Wscript.Echo "ActiveXperts Network Component " & objSnmpTrapManager.Version
Wscript.Echo "Build: " & objSnmpTrapManager.Build & vbCrLf & "Module: " & objSnmpTrapManager.Module
Wscript.Echo "License Status: " & objSnmpTrapManager.LicenseStatus & vbCrLf & "License Key: " & objSnmpTrapManager.LicenseKey & vbCrLf

' Set Logfile
Set fso = CreateObject( "Scripting.FileSystemObject")
objSnmpTrapManager.LogFile = fso.GetSpecialFolder(2) & "\SnmpTrapManager.log"
WScript.Echo "Log file: " & objSnmpTrapManager.LogFile & vbCrLf

' Get community information
strMibFile   = ReadInput( "Enter location of MIB file (optional, only required when using alpha-numeric OID's)", "", True )

If( strMibFile <> "" ) Then
   objSnmpTrapManager.LoadMibFile( strMibFile )
End If

' Set SNMPv3 authentication credentials (SHA1 or MD5)
objSnmpTrapManager.AuthProtocol	= objConstants.nwSNMP_AUTH_SHA1
objSnmpTrapManager.AuthUsername	= "user"
objSnmpTrapManager.AuthPassword = "password1"

'Set SNMPv3 encryption credentials (DES or AES)
objSnmpTrapManager.PrivProtocol = objConstants.nwSNMP_PRIV_DES
objSnmpTrapManager.PrivPassword = "password2"

'Engine ID to receive traps from
objSnmpTrapManager.EngineId 	= "80001F8880012C000059354F50"

' Start listening for incoming SNMP traps
objSnmpTrapManager.StartListening ""
WScript.Echo "StartListening, result: " & objSnmpTrapManager.LastError & " (" & objSnmpTrapManager.GetErrorDescription( objSnmpTrapManager.LastError ) & ")"

' Connection established; receive incoming traps
WScript.Echo "Waiting for incoming traps ..."

On Error Resume Next ' Useful because GetFirstTrap may return an empty (null) object

While ( True )
    Set objSnmpTrap = objSnmpTrapManager.GetFirstTrap
	
    While ( objSnmpTrapManager.LastError = 0 )
	
        PrintSnmpTrap ( objSnmpTrap )
      
        Set objSnmpTrap = objSnmpTrapManager.GetNextTrap
    Wend
	
    WScript.Sleep 1000
Wend

On Error Goto 0  ' Undo previous On Error Resume Next

' Stop listening
objSnmpTrapManager.StopListening
WScript.Echo "StopListening, result: " & objSnmpTrapManager.LastError & " (" & objSnmpTrapManager.GetErrorDescription( objSnmpTrapManager.LastError ) & ")"
WScript.Echo "Ready."

' ***************************************************************************
' Function ReadInput
' ***************************************************************************
Function ReadInput( ByVal strTitle, ByVal strDefault, ByVal bAllowEmpty )

   Dim strInput, strReturn
   
   Do
      strInput = inputbox( strTitle, "Enter value", strDefault )
      If ( strInput <> "" ) Then
         strReturn = strInput
      End If
   Loop until strReturn <> "" Or bAllowEmpty
   
   ReadInput = strReturn
End Function


' ********************************************************************
'  Function PrintSnmpTrapData
' ********************************************************************
Function PrintSnmpTrap ( objSnmpTrap )
	
   WScript.Echo
   WScript.Echo "Trap from      : " & objSnmpTrap.Host
   WScript.Echo
   WScript.Echo "Variables:"
   WScript.Echo

   Set objSnmpObject = objSnmpTrap.GetFirstObject
	
   While ( objSnmpTrap.LastError = 0 )
	
      WScript.Echo "OID        : " & objSnmpObject.OID
      WScript.Echo "Value      : " & objSnmpObject.Value   
      WScript.Echo "Type       : " & GetTypeString( objSnmpObject.Type )
      WScript.Echo "Request ID : " & objSnmpObject.RequestID
      WScript.Echo
    	
      Set objSnmpObject = objSnmpTrap.GetNextObject
   WEnd
End Function

' ********************************************************************
'  Function GetTypeString()
' ********************************************************************
Function GetTypeString( lType )
   Select Case lType
     Case objConstants.nwSNMP_TYPE_INTEGER32
        GetTypeString = "nwSNMP_TYPE_INTEGER32"
     Case objConstants.nwSNMP_TYPE_BITS 
        GetTypeString = "nwSNMP_TYPE_BITS"
     Case objConstants.nwSNMP_TYPE_OCTETSTRING 
        GetTypeString = "nwSNMP_TYPE_OCTETSTRING"
     Case objConstants.nwSNMP_TYPE_NULL 
        GetTypeString = "nwSNMP_TYPE_NULL"
     Case objConstants.nwSNMP_TYPE_OBJECTIDENTIFIER
        GetTypeString = "nwSNMP_TYPE_OBJECTIDENTIFIER"
     Case objConstants.nwSNMP_TYPE_SEQUENCE 
        GetTypeString = "nwSNMP_TYPE_SEQUENCE"
     Case objConstants.nwSNMP_TYPE_IPADDRESS 
        GetTypeString = "nwSNMP_TYPE_IPADDRESS"
     Case objConstants.nwSNMP_TYPE_COUNTER32 
        GetTypeString = "nwSNMP_TYPE_COUNTER32"
     Case objConstants.nwSNMP_TYPE_GAUGE32
        GetTypeString = "nwSNMP_TYPE_GAUGE32"
     Case objConstants.nwSNMP_TYPE_TIMETICKS 
        GetTypeString = "nwSNMP_TYPE_TIMETICKS"
     Case objConstants.nwSNMP_TYPE_OPAQUE 
        GetTypeString = "nwSNMP_TYPE_OPAQUE"
     Case objConstants.nwSNMP_TYPE_COUNTER64
        GetTypeString = "nwSNMP_TYPE_COUNTER64"
     Case objConstants.nwSNMP_TYPE_UNSIGNED32 
        GetTypeString = "nwSNMP_TYPE_UNSIGNED32"
     Case Else 
        GetTypeString= "UNKNOWN" 
   End Select 
End Function

You can download the complete sample on our FTP site ftp.activexperts-labs.com/samples/network-component/. There are many other working Network Component scripts on our site and shipped with the product.